Excel VBAで複数人で別々のID、パスワードでブックを開くようにしてみた

Function Get_UserInfo(user_id As String) As Variant
    
    '検索結果用
        '0 = パスワード
        '1 = ヒットしたセル
    Dim result_array(1) As Variant
    
    'ユーザーを探す
    Set result_array(1) = ThisWorkbook.Worksheets("user").Range("A:A").Find(user_id, LookAt:=xlWhole, MatchCase:=True)
    
    'ヒットした場合、パスワードを返す
    If Not result_array(1) Is Nothing Then
        result_array(0) = result_array(1).Offset(0, 1).Value
    'ヒットしなかった場合
    Else
        result_array(0) = ""
    End If
    
    Get_UserInfo = result_array
    
End Function

Sub shUser_ReProtect()

    '管理者（admin）パスワード用
    Dim admin_info As Variant
    
    '管理者（admin）パスワード取得
    admin_info = Get_UserInfo("admin")

    'シート保護解除
    If admin_info(0) <> "" Then
        ThisWorkbook.Worksheets("user").Protect Password:=admin_info(0), UserInterfaceOnly:=True
    End If

End Sub

Function User_LoginCheck() As Boolean
    'ログインチェック
    User_LoginCheck = False
    '「user」シートのC列に○があるか
    If WorksheetFunction.CountIf(ThisWorkbook.Worksheets("user").Range("C:C"), "○") > 0 Then
        User_LoginCheck = True
    End If
End Function

Private Sub Workbook_Open()
    'このブック操作
    With ThisWorkbook
        '「user」シート操作
        With .Worksheets("user")
            'シート再度保護
            shUser_ReProtect
            'ログイン状態列消去
            .Range("C:C").Value = ""
            '背景色を透明
            .Cells.Interior.ColorIndex = 0
            '文字の色を白に
            .Cells.Font.Color = RGB(255, 255, 255)
            'A1をselect
            .Activate
            .Range("A1").Select
            'シート非表示
            .Visible = False
        End With
        '「start」シートアクティブ
        .Worksheets("start").Activate
    End With
    
    'ログインフォームを開く
    F_Login.Show
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    'このブック操作
    With ThisWorkbook
        '「start」シートをアクティブ
        .Worksheets("start").Activate
        '上書き保存
        .Save
    End With
End Sub

Option Explicit

'このブック用
Dim wb As Workbook

Private Sub LoginButton_Click()
    If user_id_txt.Value = "" Or password_txt.Value = "" Then
        MsgBox "ユーザーID、パスワード未入力"
        Exit Sub
    End If
    
    '検索結果用
    Dim get_user As Variant
    
    'フォームで入力されたユーザーID用
    Dim user_txt As String
    'フォームで入力されたパスワード用
    Dim pass_txt As String
    '登録されているパスワード用
    Dim pass_txt_touroku As String
    
    'このブック
    Set wb = ThisWorkbook
    
    'フォームで入力されたユーザーIDを代入
    user_txt = user_id_txt.Value
    'フォームで入力されたパスワードを代入
    pass_txt = password_txt.Value

    'ユーザー情報取得
    get_user = Get_UserInfo(user_txt)

    'ユーザー情報がない場合
    If get_user(1) Is Nothing Then
        MsgBox "ユーザーIDまたはパスワードが違います"
        user_id_txt.SetFocus
    'ユーザー情報がある場合
    Else
        'パスワードが一致した場合
        If pass_txt = get_user(0) Then
            '「user」シート再度保護
            shUser_ReProtect
            'ログイン者に○
            get_user(1).Offset(0, 2).Value = "〇"
            '「メニュー」シートをアクティブ
            wb.Worksheets("メニュー").Activate
            'ログインフォームを閉じる
            F_Login.Hide
        'パスワードが一致しない場合
        Else
            MsgBox "ユーザーIDまたはパスワードが違います"
            user_id_txt.SetFocus
        End If
    End If

End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    Dim user_login As Boolean
    
    'このブック
    Set wb = ThisWorkbook
    
    'ログインしていなかったらブックを閉じる
    user_login = User_LoginCheck
    If user_login = False Then
        wb.Close savechanges:=False
    End If
End Sub